[inizio] [indice generale] [precedente] [successivo] [indice analitico] [contributi]


166. Perl: gestione delle stringhe

La gestione delle stringhe da parte di Perl è fatta attraverso gli operatori di delimitazione delle stringhe stesse e le espressioni regolari. È questo insieme di cose che rende Perl uno strumento valido per la gestione dei file di testo.

166.1 Operatori di delimitazione di stringhe

Nella sezione dedicata agli operatori e alle espressioni erano rimasti in sospeso gli operatori di delimitazione di stringhe. Nei linguaggi di programmazione tradizionale esiste normalmente il problema di delimitare le stringhe, ovvero le costanti alfanumeriche. Si era detto che in Perl ci sono due tipi di delimitatori, gli apici doppi e singoli che hanno un comportamento simile a quello delle shell comuni. In realtà Perl ha una gestione molto più raffinata e generalizzata delle stringhe. Quando il tipo di delimitazione, ovvero il tipo di stringa, lo consente, sono validi alcuni codici di escape. La tabella 166.1 mostra l'elenco di queste sequenze di escape utilizzabili nelle stringhe.

Escape Corrispondenza
\\ \
\" "
\$ $
\@ @
\' '
\t <HT>
\n <LF>
\r <CR>
\f <FF>
\a <BEL>
\e <ESC>
\0n Numero ottale rappresentato da n.
\xh Numero esadecimale rappresentato da h.
\[ Carattere di controllo.
\l Il carattere successivo in minuscolo.
\u Il carattere successivo in maiuscolo.
\L Minuscolo fino al codice `\E'.
\U Maiuscolo fino al codice `\E'.
\E Conclusione di un modificatore.
\Q Evita l'interpretazione come espressione regolare fino al codice `\E'.

Tabella 166.1: Elenco delle sequenze di escape utilizzabili nelle stringhe delimitate con gli apici doppi.

La delimitazione dei vari tipi di stringa avviene in una forma tradizionale, attraverso delimitatori che esprimono di per sé il tipo di stringa, oppure attraverso una forma che consente di cambiare tipo di delimitatore:

x<delim-sinistro><stringa><delim-destro><eventuali-opzioni>

La sigla che appare inizialmente, x in questo caso, definisce il tipo di stringa; il delimitatore sinistro e quello destro possono essere parentesi aperte e chiuse di qualunque tipo: tonde, quadre, graffe e angolari, ma si possono utilizzare anche altri simboli, solo che in tal caso, il delimitatore sinistro e quello destro saranno uguali.

La tabella 166.5, alla fine di questo gruppo di sezioni, riassume i vari tipi di operatori di delimitazione delle stringhe.

166.1.1 q | ' ' -- stringa letterale non interpolata

Si tratta della stringa racchiusa normalmente tra apici singoli. È già stata descritta in precedenza. In particolare, restituisce la stringa racchiusa senza effettuare l'interpolazione delle eventuali variabili e dei simboli di escape che dovesse incorporare, a eccezione di `\'' e `\\'. Si può esprimere in due modi.

'<stringa>'

q<delim-sinistro><stringa><delim-destro>

Seguono alcuni esempi.

$miavar = 'Stringa tradizionale che non interpola';

$miavar = q|Una stringa che "contiene 'apici' di ogni tipo".|;

$miavar = q(Sembra una funzione, ma non lo è);

$miavar = q{Le variabili non vengono interpolate. $ciao};

166.1.2 qq | " " -- stringa letterale interpolata

Si tratta della stringa racchiusa normalmente tra apici doppi. È già stata descritta in precedenza. In particolare, restituisce la stringa racchiusa interpolando le variabili e i simboli di escape che dovesse incorporare. Si può esprimere in due modi.

"<stringa>"

qq<delim-sinistro><stringa><delim-destro>

Seguono alcuni esempi.

$miavar = "Stringa tradizionale che interpola";

$miavar = qq|Una stringa che \"contiene 'apici' di ogni tipo\".|;

$miavar = qq(Sembra una funzione, ma non lo è);

$ciao = "Saluti!";
$miavar = qq{Le variabili vengono interpolate. $ciao};

166.1.3 qx | ` ` -- comando di sistema

Si tratta di stringhe il cui contenuto deve essere valutato e successivamente eseguito come comando dal sistema operativo. Questo tipo di stringa è racchiuso normalmente tra apici singoli inversi, come avviene nelle shell comuni. Il contenuto della stringa viene interpolato prima dell'esecuzione del comando. La valutazione della stringa si traduce nell'output emesso attraverso lo standard output dal comando stesso. Si può esprimere in due modi.

`<stringa>`

qx<delim-sinistro><stringa><delim-destro>

Seguono alcuni esempi.

$miadata = `date`;

$mioelenco = qx(ls);

$opzioni = '-l'
$mioelenco = qx{ls $opzioni};

166.1.4 qw -- lista di parole

La stringa racchiusa in questo tipo di delimitazione, non viene interpolata, ma semplicemente restituita in forma di lista di parole. In pratica, tutto ciò che risulta separato da spazi (spazi veri e propri, caratteri di tabulazione e codici di interruzione di riga) viene estratto e inserito in una lista di elementi. Si può esprimere solo nel modo seguente:

qw<delim-sinistro><stringa><delim-destro>

Seguono alcuni esempi validi.

@mialista = qw/ciao come stai/;

@mialista = qw(uno	due	tre);

@mialista = qw(alfa	bravo	charlie
delta	echo	foxtrot	golf	hotel
india	kilo	lima);

166.1.5 m | // -- modello di confronto

Definisce un modello di confronto con una stringa. Non restituisce alcunché; serve per essere paragonato a un'altra stringa. Può essere usato in un contesto scalare o lista. Nel primo caso serve a determinare se esiste una corrispondenza con il modello o meno. Nel secondo caso, viene sempre paragonato a un'altra stringa, ma il risultato di questo abbinamento è una lista di elementi.

Il modello si esprime in forma di espressione regolare, con delle particolarità che derivano dal tipo di delimitatori utilizzati e dal fatto che prima di valutare l'espressione regolare viene eseguita un'interpolazione. Si può esprimere in due modi.

/<stringa>/<opzioni>

m<delim-sinistro><stringa><delim-destro><modificatori>

I modificatori si esprimono con una serie di lettere, o nulla se non è necessario. La tabella 166.2 ne riporta l'elenco.

Modificatore Descrizione
i Il confronto avviene ignorando la differenza tra maiuscole e minuscole.
m Le stringhe vengono trattate come righe multiple (riguarda `^' e `$').
s Tratta le stringhe come una riga singola (riguarda `.').
x Permette l'inserzione di spazi e commenti che non vengono interpretati.
g Confronta in modo globale, cioè trova tutte le occorrenze.
o Interpreta il modello (e di conseguenza lo interpola) solo la prima volta.

Tabella 166.2: Elenco dei modificatori utilizzabili con l'operatore di delimitazione `m'.

L'utilizzo delle espressioni regolari nelle istruzioni Perl è ciò che generalmente rende il sorgente di un programma piuttosto confuso. Se si devono utilizzare intensivamente le espressioni regolari sarebbe opportuno approfondirne il funzionamento e l'utilizzo di questo tipo di delimitatori, per trovare un modo meno complicato del solito di scrivere queste espressioni. Il primo punto su cui si può intervenire è la scelta dei simboli di delimitazione. La forma tradizionale prevede l'uso della barra obliqua normale, cosa però che crea problemi quando si vuole utilizzare questo simbolo all'interno dell'espressione stessa. Infatti, i simboli usati come delimitazione non possono essere utilizzati nell'espressione regolare senza la tecnica della protezione per mezzo del prefisso `\'.

Esempi

#!/usr/bin/perl

$miafrase = 'Ciao, come stai?';
if ( $miafrase =~ /ciao/i ) {
	print "Ciao!\n";
}

In questo esempio, il modello `/ciao/i' combacia con una parte della frase, facendo sì che la condizione si avveri.

#!/usr/bin/perl

$mioelenco = `ls`;
if ( $mioelenco =~ /.*\.pl/ ) {
	print "Ci sono programmi Perl in questa directory.\n";
}

In questo esempio, viene letto il contenuto della directory corrente e posto nella variabile `$mioelenco'. Successivamente viene verificato se in quell'elenco si trova qualcosa che termina con `.pl'. Dal momento che il punto ha un significato nelle espressioni regolari, per poterlo includere si è posta anteriormente una barra obliqua inversa.

166.1.6 s -- modello di sostituzione

Definisce un modello di confronto con una stringa, e una stringa di sostituzione per la parte che corrisponde al modello. Se il confronto non viene fatto attraverso gli operatori `=~' oppure `!~', si intende che l'abbinamento avvenga con il contenuto della variabile `$_'. Ha luogo l'interpolazione.

L'abbinamento per la sostituzione può avvenire solo in un contesto scalare. Il modello si esprime in forma di espressione regolare. La sintassi può essere espressa in due modi, a seconda del tipo di delimitatori utilizzati.

s<delim-sx><stringa><delim-dx><delim-sx><rimpiazzo><delim-dx><modificatori>

s<delim><stringa><delim><rimpiazzo><delim><modificatori>

Il primo tipo di sintassi si adatta al caso in cui si usino parentesi per delimitare le stringhe del modello e del rimpiazzo, il secondo tipo si riferisce all'uso di altri simboli che non sono utilizzati in coppia.

I modificatori si esprimono con una serie di lettere, o nulla se ciò non è necessario. La tabella 166.3 ne riporta l'elenco.

Modificatore Descrizione
i Il confronto avviene ignorando la differenza tra maiuscole e minuscole.
m Le stringhe vengono trattate come righe multiple (riguarda `^' e `$').
s Tratta le stringhe come una singola riga (riguarda `.').
x Permette l'inserzione di spazi e commenti che non vengono interpretati.
g Confronta in modo globale, cioè trova tutte le occorrenze.
o Interpreta il modello (e di conseguenza lo interpola) solo la prima volta.
e Valuta la parte destra come un'espressione.

Tabella 166.3: Elenco dei modificatori utilizzabili con l'operatore di delimitazione `s'.

Esempi

$path =~ s|/usr/bin|/usr/local/bin|

Sostituisce la prima occorrenza di `/usr/bin' nella variabile `$path' con `/usr/local/bin'. Per delimitare il modello e la stringa di sostituzione sono state usate le barre verticali, per evitare ambiguità con le barre oblique delle directory.

$path =~ s{/usr/bin}{/usr/local/bin}

Esattamente come nell'esempio precedente, ma questa volta sono state usate le parentesi graffe.

166.1.7 tr | y -- traslazione di caratteri

Definisce un modello di sostituzione di una serie di caratteri in un'altra. Si applica al contenuto di una variabile scalare utilizzando l'operatore `=~' oppure `!~', altrimenti si intente la variabile `$_'. Restituisce il numero di trasformazioni eseguite. Non ha luogo l'interpolazione.

L'abbinamento per la sostituzione può avvenire solo in un contesto scalare. Il modello si esprime in forma di espressione regolare. La sintassi può essere espressa nei modi seguenti, a seconda che si voglia utilizzare l'identificatore `tr' o `y' e a seconda del tipo di delimitatori utilizzati.

tr<delim-sx><car-da-sost><delim-dx><delim-sx><rimpiazzo><delim-dx><modificatori>

tr<delim><car-da-sostituire><delim><rimpiazzo><delim><modificatori>

y<delim-sx><car-da-sost><delim-dx><delim-sx><rimpiazzo><delim-dx><modificatori>

y<delim><car-da-sostituire><delim><rimpiazzo><delim><modificatori>

I modificatori si esprimono con una serie di lettere, o nulla se ciò non è necessario. La tabella 166.4 ne riporta l'elenco.

Modificatore Descrizione
c Cerca gli elementi che non sono elencati nel gruppo da sostituire.
d Cancella i caratteri trovati e non rimpiazzati.
s Fonde insieme i caratteri doppi che sono stati ritrovati.

Tabella 166.4: Elenco dei modificatori utilizzabili con l'operatore di delimitazione `tr'.

Esempi

$miavar =~ tr/A-Z/a-z/;

Converte in minuscolo il contenuto della variabile (a parte le vocali accentate).

$contatore = ( $miavar =~ tr/0-9// );

Conta i caratteri numerici contenuti nella variabile `$miavar'.

Formato normale Formato generico Significato Interpolazione
' ' q{} Stringa letterale. NO
" " qq{} Stringa letterale.
` ` qx{} Comando di sistema.
qw{} Lista di parole. NO
/ / m{} Modello di confronto.
s{}{} Modello di sostituzione.
tr{}{} Traslazione di caratteri.

Tabella 166.5: Elenco riassuntivo dei tipi di operatori di stringa. Le parentesi graffe rappresentano la posizione dei delimitatori.

166.2 Espressioni regolari

Le espressioni regolari possono essere considerate l'elemento più potente e più difficile di Perl. Purtroppo non esiste una definizione e uno standard universale delle espressioni regolari, così, per ogni applicazione che ne fa uso occorre studiarne le particolarità.

In questa sezione si descrive solo parte delle potenzialità di Perl con le espressioni regolari. Per conoscerne i dettagli è necessario consultare la pagina di manuale perlre(1). Può essere conveniente anche la lettura della sezione 61.1 e del capitolo 182.

166.2.1 Modificatori

Perl utilizza le espressioni regolari con gli operatori di stringa `m{}' e `s{}{}'. Con questi è possibile utilizzare delle opzioni finali, ovvero dei modificatori, che alterano le regole delle espressioni regolari. La tabella 166.6 mostra l'elenco dei modificatori più comuni.

Modificatore Descrizione
i Il confronto avviene ignorando la differenza tra maiuscole e minuscole.
m Le stringhe vengono trattate come righe multiple (riguarda `^' e `$').
s Tratta le stringhe come una singola riga (riguarda `.').
x Permette l'inserzione di spazi e commenti che non vengono interpretati.

Tabella 166.6: Elenco dei modificatori utilizzabili in generale in coda alle espressioni regolari di Perl.

166.2.2 Metacaratteri

In generale, i caratteri utilizzati in un'espressione regolare, che non abbiano un significato speciale, corrispondono a loro stessi nella stringa di comparazione. Ciò è come dire che la comparazione seguente è valida.

'Ciao' =~ /Ciao/

I metacaratteri di un'espressione regolare sono dei simboli che hanno un significato diverso rispetto ai caratteri utilizzati per rappresentarli. La tabella 166.7 mostra l'elenco dei metacaratteri più comuni.

Metacarattere Descrizione
\ Protegge il carattere seguente da un'interpretazione diversa da quella letterale.
^ Corrisponde all'inizio di una riga.
. Corrisponde a un carattere qualunque.
$ Corrisponde alla fine di una riga.
| Indica due possibilità alternative alla sua sinistra e alla sua destra.
( ) Definiscono un raggruppamento.
[ ] Definiscono una classe di caratteri.

Tabella 166.7: Elenco dei metacaratteri standard utilizzati in Perl.

La barra obliqua inversa protegge il carattere successivo da un'interpretazione diversa da quella letterale, quando la sequenza `\x' (x rappresenta qui un carattere qualunque) non rappresenta già un metacarattere. In pratica, se `\x' non ha un significato particolare, rappresenta semplicemente `x' in modo letterale.

L'accento circonflesso (`^') corrisponde generalmente all'inizio di una riga; nello stesso modo, il simbolo dollaro (`$') rappresenta la fine di una riga. Questi metacaratteri rappresentano in pratica la stringa nulla di inizio e di fine di una riga. Se la stringa da analizzare è composta da più righe terminate dal codice di interruzione di riga, è possibile fare in modo che `^' e `$' corrispondano all'inizio e alla fine di queste righe virtuali utilizzando il modificatore `m'.

Il punto rappresenta un carattere singolo, con l'esclusione del codice di interruzione di riga a meno che sia stato utilizzando il modificatore `s'.

Perl aggiunge a quelli standard una serie di metacaratteri rappresentati dalla tabella 166.8.

Metacarattere Corrispondenza
\w Un carattere alfanumerico (lettere e numeri) compreso il simbolo di sottolineato.
\W Un carattere non alfanumerico (l'opposto di `\w').
\s Uno spazio lineare (spazio o tabulazione).
\S Qualunque carattere che non sia uno spazio lineare.
\d Un carattere numerico.
\D Un carattere non numerico.
\b La stringa nulla prima o dopo una sequenza di caratteri corrispondenti a `\w'.
\B La stringa nulla interna a una sequenza di caratteri corrispondenti a `\w'.
\A L'inizio di una stringa.
\Z La fine di una stringa (eventualmente prima di un newline finale).

Tabella 166.8: Elenco dei metacaratteri speciali di Perl.

Inoltre, per complicare ulteriormente le cose, le espressioni regolari di Perl vengono trattate come se fossero racchiuse tra apici doppi, cioè vengono interpolate prima di essere valutate come espressioni regolari. Questo significa che le variabili vengono espanse e vengono riconosciuti anche altri simboli che in pratica potrebbero essere considerati come dei metacaratteri aggiuntivi. Si tratta di `\n', `\t' e altri come già indicato nella tabella 166.1 all'inizio del capitolo.

166.2.3 Classi di caratteri

Un modello racchiuso tra parentesi quadre rappresenta un solo carattere in base a quanto indicato nelle parentesi.

Una fila di caratteri racchiusa tra parentesi quadre corrisponde a un carattere qualunque tra quelli indicati; se all'inizio di questa fila c'è l'accento circonflesso, si ottiene una corrispondenza con un carattere qualunque diverso da quelli della fila. Per esempio, l'espressione regolare `[0123456789]' corrisponde a una cifra numerica qualunque, mentre `[^0123456789]' corrisponde a un carattere qualunque purché non sia una cifra numerica.

All'interno delle parentesi quadre, invece che indicare un insieme di caratteri, è possibile indicarne un intervallo mettendo il carattere iniziale e finale separati da un trattino (`-'). I caratteri che vengono rappresentati in questo modo dipendono dalla codifica ASCII che ne determina la sequenza. Per esempio, l'espressione regolare `[9-A]' rappresenta un carattere qualsiasi tra: `9', `:', `;', `<', `=', `>', `?', `@' e `A', perché così è la sequenza ASCII.

Questa definizione corrisponde in parte a quella di `grep' GNU, in particolare si deve tenere presente che all'interno delle parentesi quadre, `\b' corrisponde al carattere <BS>.

Un'altra diversità rispetto alle espressioni regolari di altri programmi sta nella mancanza di classi di caratteri espresse attraverso una denominazione. Ciò giustifica la presenza di metacaratteri che non ci sono normalmente. La tabella 166.9 mostra l'abbinamento tra le classi delle espressioni regolari comuni e i metacaratteri corrispondenti di Perl.

Perl Espressioni regolari POSIX
\w [[:alnum:]]
\W [^[:alnum:]]
\s [[:space:]]
\S [^[:space:]]
\d [[:digit:]]
\D [^[:digit:]]

Tabella 166.9: Comparazione tra alcuni metacaratteri di Perl e le classi di caratteri equivalenti delle espressioni regolari POSIX.

166.2.4 Qualificatori -- operatori di ripetizione

Attraverso altri simboli è possibile indicare la ripetizione di un carattere determinato o di un raggruppamento. La tabella 166.10 mostra l'elenco di queste notazioni e il loro significato.

Codifica Corrispondenza.
x* Nessuna o più volte x. Equivalente a `x{0,}'.
x? Nessuna o al massimo una volta x. Equivalente a `x{0,1}'.
x+ Una o più volte x. Equivalente a `x{1,}'.
x{n} Esattamente n volte x.
x{n,} Almeno n volte x.
x{n,m} Da n a m volte x.
x*? Equivale al minimo di `x*'.
x?? Equivale al minimo di `x?'.
x+? Equivale al minimo di `x+'.
x{n}? Equivale al minimo di `x{n}', ovvero allo stesso `x{n}'.
x{n,}? Equivale al minimo di `x{n,}'.
x{n,m}? Equivale al minimo di `x{n,m}'.

Tabella 166.10: Operatori di ripetizione, o qualificatori, nelle espressioni regolari di Perl.

Dalla tabella si può osservare la presenza di qualificatori insoliti che terminano con un punto interrogativo. Un modello espresso in forma di espressione regolare può corrispondere a una stringa in diversi modi. Generalmente, la corrispondenza dei qualificatori avviene nel modo più ampio possibile. Se è necessario fare in modo che la corrispondenza avvenga nel modo più ristretto possibile, occorre utilizzare i qualificatori che terminano con il punto interrogativo. Per esempio, di seguito si vedono alcune corrispondenze valide e le zone delle stringhe originali in cui i modelli combaciano.

"CIAO" =~ /\w+/
 ^--^

"Ciao, come stai?" =~ /\s/
      ^

"Ciao, come stai? Io sto bene." =~ /\s.*\s/
      ^-----------------^

"Ciao, come stai? Io sto bene." =~ /\s.*?\s/
      ^----^

166.2.5 Raggruppamenti

Una o più parti di un'espressione regolare possono essere raggruppate attraverso l'uso delle parentesi tonde. Ciò permette di abbinare tali raggruppamenti ai qualificatori (gli operatori di ripetizione), oppure permette di estrarre ciò che corrisponde al segmento racchiuso tra parentesi, o di potervi fare riferimento. Per esempio, l'espressione `\s(come\s)+.*\s' è valida per tutte le stringhe seguenti.

"Ciao, come stai? Io sto bene."
"Ciao, come come stai? Io sto bene."
"Ciao, come come come stai? Io sto bene."
...

All'interno della stessa espressione regolare è possibile fare riferimento a una corrispondenza parziale contenuta in un raggruppamento. Per farlo si utilizza il metacarattere `\n', dove n è una sola cifra numerica. In pratica, `\1' corrisponde al primo raggruppamento, `\2' corrisponde al secondo, e così di seguito, fino al nono.

Per esempio, `(0|0x0)\d*\s\1\d*' è valida per `0x0123 0x0456', ma non per `0x0123 0456'. Infatti, si fa riferimento alla corrispondenza, non al modello che potrebbe essere ripetuto agevolmente.

Perl permette di utilizzare queste corrispondenze anche al di fuori delle espressioni regolari. Per questo però non si può più utilizzare la notazione `\n', ma occorre utilizzare `$n'. In pratica si tratta di variabili predefinite che vengono generate per l'occasione. Per esempio,

s/^(\w+)\s+(\w+)/$2 $1/

inverte le prime due parole, ed elimina gli spazi superflui tra le due. Un altro esempio interessante è il seguente, in cui si estrae la data da una stringa, per gestirla all'interno del programma.

if ( $miadata =~ m|Data:\s+(\d\d)/(\d\d)/(\d{2,4})| ) {
	$giorno = $1;
	$mese = $2;
	$anno = $3;
}

Come si può vedere, i delimitatori dell'espressione regolare sono stati sostituiti con le barre verticali, in modo da poter utilizzare le barre oblique per l'espressione stessa senza troppi problemi.

---------------------------

Appunti Linux 2000.04.12 --- Copyright © 1997-2000 Daniele Giacomini --  daniele @ pluto.linux.it


[inizio] [indice generale] [precedente] [successivo] [indice analitico] [contributi]